//=====================================================================================================================//
// email: nikolaospantzos@gmail.com                                                                      HistoryInfoEA //
//=====================================================================================================================//
#property copyright   "Copyright 2016-2017, Nikolaos Pantzos"
#property link        "https://www.mql5.com/en/users/pannik"
#property version     "1.0"
#property description "\nIt's a history orders' information tool."
#property description "\nPlace Magic Number Or Comment, in the corresponding position, Of Orders You Want To Count."
//#property icon        "\\Images\\HistoryInfo-Logo.ico";
#property strict
//=====================================================================================================================//
extern string InfoToUse  = "Place Magic Number Or Comment Of Orders You Want To Count";
extern int    MagicNumber= 0;
extern string OrdersComm = "OrdersComment";
//------------------------------------------------------
int MultiplierPoint;
color ChartColor;
string BackgroundName;
//=====================================================================================================================//
int OnInit()
  {
//------------------------------------------------------
//Background
   BackgroundName="Background-"+WindowExpertName();
   ChartColor=(color)ChartGetInteger(0,CHART_COLOR_BACKGROUND,0);
//---
   if(ObjectFind(BackgroundName)==-1)
     {
      ObjectCreate(BackgroundName,OBJ_LABEL,0,0,0);
      ObjectSet(BackgroundName,OBJPROP_CORNER,0);
      ObjectSet(BackgroundName,OBJPROP_BACK,FALSE);
      ObjectSet(BackgroundName,OBJPROP_YDISTANCE,14);
      ObjectSet(BackgroundName,OBJPROP_XDISTANCE,0);
      ObjectSetText(BackgroundName,"g",120,"Webdings",ChartColor);
     }
//------------------------------------------------------
//Calculate for 4 or 5 digits broker
   MultiplierPoint=1;
//---
   if((MarketInfo(Symbol(),MODE_DIGITS)==3) || (MarketInfo(Symbol(),MODE_DIGITS)==5)) MultiplierPoint=10;
//------------------------------------------------------
   OnTick();
   return(INIT_SUCCEEDED);
  }
//=====================================================================================================================//
void OnDeinit(const int reason)
  {
//----
   ObjectDelete(BackgroundName);
   Comment("");
//----
  }
//=====================================================================================================================//
void OnTick()
  {
   string Comments;
   string MagicNo;
   string FirstOrderStr;
   string LastOrderStr;
   double TotalProfit=0;
   double TotalPips=0;
   double TotalLots=0;
   int TotalOrders=0;
   datetime FirstOrder=TimeCurrent();
   datetime LastOrder=0;
//---
   for(int i=0; i<OrdersHistoryTotal(); i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_HISTORY))
        {
         if((OrderComment()==OrdersComm) || (OrderMagicNumber()==MagicNumber))
           {
            FirstOrder=MathMin(FirstOrder,OrderOpenTime());
            LastOrder=MathMax(LastOrder,OrderOpenTime());
            TotalOrders++;
            TotalProfit+=OrderProfit()+OrderCommission()+OrderSwap();
            TotalLots+=OrderLots();
            if(OrderType()==OP_BUY) TotalPips+=(OrderClosePrice()-OrderOpenPrice())/(MarketInfo(OrderSymbol(),MODE_POINT)*MultiplierPoint);
            if(OrderType()==OP_SELL) TotalPips+=(OrderOpenPrice()-OrderClosePrice())/(MarketInfo(OrderSymbol(),MODE_POINT)*MultiplierPoint);
           }
        }
     }
//----
   if(FirstOrder==TimeCurrent()) FirstOrderStr="EMPTY VALUE";
   if(LastOrder==0) LastOrderStr="EMPTY VALUE";
   if(FirstOrder!=TimeCurrent()) FirstOrderStr=TimeToStr(FirstOrder,TIME_DATE)+" || "+TimeToStr(FirstOrder,TIME_MINUTES);
   if(LastOrder!=0) LastOrderStr=TimeToStr(LastOrder,TIME_DATE)+" || "+TimeToStr(LastOrder,TIME_MINUTES);
//----
   if((MagicNumber!=0) && (OrdersComm=="OrdersComment"))
     {
      MagicNo="Magic No: "+IntegerToString(MagicNumber);
      Comments="Comment: EMPTY VALUE";
     }
//----
   if((MagicNumber==0) && (OrdersComm!="OrdersComment"))
     {
      MagicNo="Magic No: EMPTY VALUE";
      Comments="Comment: "+OrdersComm;
     }
//----
   if((MagicNumber!=0) && (OrdersComm!="OrdersComment"))
     {
      MagicNo="Magic No: "+IntegerToString(MagicNumber);
      Comments="Comment: "+OrdersComm;
     }
//----
   if((MagicNumber==0) && (OrdersComm=="OrdersComment"))
     {
      MagicNo="Magic No: EMPTY VALUE";
      Comments="Comment: EMPTY VALUE";
     }
//----
   Comment("======================"+
           "\n First Order: "+FirstOrderStr+
           "\n Last Order : "+LastOrderStr+
           "\n======================"+
           "\n Count History By ID or Comment"+
           "\n "+Comments+
           "\n "+MagicNo+
           "\n======================"+
           "\n Total Lots    : "+DoubleToStr(TotalLots,2)+
           "\n Total Pips    : "+DoubleToStr(TotalPips,2)+
           "\n Total Profit  : "+DoubleToStr(TotalProfit,2)+
           "\n Total Orders: "+DoubleToStr(TotalOrders,0)+
           "\n======================");
//----
  }
//=====================================================================================================================//