//+------------------------------------------------------------------+
//|                                                     Followme.mq4 |
//|                                                            Roger |
//|                                      http://www.rogersignals.com |
//+------------------------------------------------------------------+
#property copyright "Roger"
#property link      "http://www.rogersignals.com"

//Советник для ручного тестирования стратегий. Запустите тестер, выберите нужный
//таймфрейм, пару валют, качество тестирования, даты начала и конца и режим
//Визуализация. Сразу после старта нажмите Паузу. В открывшемся графике увидите
//две линии, голубую - для ордеров на покупку, желтую - для ордеров на продажу.
//Пока Вы не трогаете эти линии, ничего не произойдет.
//Вы можете бросить на график любые индикаторы. Манипулируя кнопкой Пуск/Пауза,
//Вы можете останавливать ход процесса в любой момент.
//Если Вам необходимо открыть ордер на покупку, выделите голубую линию и потяните
//ее на место предполагаемого открытия. Уберите Паузу, сразу же откроется ордер.
//Если расстояние между Бидом и линией было меньше допустимого уровня стопа, откроется
//покупка. Если линия была выше - откроется стоповый ордер, ниже - лимитный.
//Чтобы закрыть ордер, достаточно потянуть любую линию, но откроется другой ордер.
//Если параметр NoStops поставить в false, появятся линии стопов и тейков, т.е.
//Вы сразу сможете установить необходимые стопы и тейки в новом ордере.
//Если Вам какая-нибудь линия не нужна, выделите ее и удалите, но помните, при
//удалении удалятся все выделенные линии, т.е., если Вы забыли, что что-то еще 
//выделили, то оно все равно удалится.
//---- input parameters
extern double    Lots=0.1;
extern bool      NoStops=true; 
double prbuy,prbuyt,prbuys,prsell,prsellt,prsells;
//+------------------------------------------------------------------+
//| expert initialization function                                   |
//+------------------------------------------------------------------+
int init()
  {
//----
drawline();//рисуем линии
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function                                 |
//+------------------------------------------------------------------+
int deinit()
  {
//----
 ObjectDelete("BUY");  //подчищаем хвосты
 ObjectDelete("SELL");  
 ObjectDelete("BUYT");  
 ObjectDelete("SELLT");  
 ObjectDelete("BUYS");  
 ObjectDelete("SELLS");  
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+
int start()
  {
//----
   double nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells,stl,tpr;
   int stlev=MarketInfo(Symbol(),MODE_STOPLEVEL);//уровень стоплевел
   int ticket;
   if(ObjectFind("BUY")==-1&&ObjectFind("SELL")==-1)drawline();//если линии стерлись от наложения шаблона
   nprbuy=NormalizeDouble(ObjectGet("BUY",OBJPROP_PRICE1),Digits);
   if(ObjectFind("BUYT")!=-1)nprbuyt=NormalizeDouble(ObjectGet("BUYT",OBJPROP_PRICE1),Digits);
   if(ObjectFind("BUYS")!=-1)nprbuys=NormalizeDouble(ObjectGet("BUYS",OBJPROP_PRICE1),Digits);
   nprsell=NormalizeDouble(ObjectGet("SELL",OBJPROP_PRICE1),Digits);
   if(ObjectFind("SELLT")!=-1)nprsellt=NormalizeDouble(ObjectGet("SELLT",OBJPROP_PRICE1),Digits);
   if(ObjectFind("SELLS")!=-1)nprsells=NormalizeDouble(ObjectGet("SELLS",OBJPROP_PRICE1),Digits);
   if(nprbuy==prbuy&&nprbuyt==prbuyt&&nprbuys==prbuys&&nprsell==prsell&&nprsellt==prsellt&&nprsells==prsells)return(0);//если все как было, уходим
   if(nprbuy!=prbuy||nprsell!=prsell)//если двигали линии купли или продажи
      {
      if(OrdersTotal()>0)closeord();//сначала удалим все открытые ордера
      if(nprbuy!=prbuy)//для ордеров покупки
         {
         if(nprbuyt-nprbuy<=stlev*Point||nprbuyt==0)tpr=0;
         else tpr=nprbuyt;
         if(nprbuy-nprbuys<=stlev*Point||nprbuys==0)stl=0;
         else stl=nprbuys;
         if(MathAbs(Bid-nprbuy)<=stlev*Point)
            {
            ticket=OrderSend(Symbol(),OP_BUY,Lots,Ask,3,stl,tpr);
            if(ticket==-1)  Print("ErrorBuy - ",GetLastError()); 
            else 
               {
               Print("PriceBuy - ",Ask," Stop - ",stl," Take - ",tpr);
               equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
               }
            }
         else if(Bid>nprbuy)
            {
            ticket=OrderSend(Symbol(),OP_BUYLIMIT,Lots,nprbuy,3,stl,tpr);
            if(ticket==-1)  Print("ErrorBuyLimit - ",GetLastError()); 
            else 
               {
               Print("PriceBuyLimit - ",nprbuy," Stop - ",stl," Take - ",tpr);
               equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
               }
            }
         else 
            {
            ticket=OrderSend(Symbol(),OP_BUYSTOP,Lots,nprbuy,3,stl,tpr);
            if(ticket==-1)  Print("ErrorBuySell - ",GetLastError()); 
            else 
               {
               Print("PriceBuyStop - ",nprbuy," Stop - ",stl," Take - ",tpr);
               equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
               }
            }
         }
      else//для ордеров продажи
         {
         if(nprsell-nprsellt<=stlev*Point||nprsellt==0)tpr=0;
         else tpr=nprsellt;
         if(nprsells-nprsell<=stlev*Point||nprsells==0)stl=0;
         else stl=nprsells;
         if(MathAbs(Bid-nprsell)<=stlev*Point)
            {
            ticket=OrderSend(Symbol(),OP_SELL,Lots,Bid,3,stl,tpr);
            if(ticket==-1)  Print("ErrorSell - ",GetLastError()); 
            else 
               {
               Print("PriceSell - ",Bid," Stop - ",stl," Take - ",tpr);
               equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
               }
            }
         else if(Bid<nprsell)
            {
            ticket=OrderSend(Symbol(),OP_SELLLIMIT,Lots,nprsell,3,stl,tpr);
            if(ticket==-1)  Print("ErrorSellLimit - ",GetLastError()); 
            else 
               {
               Print("PriceSellLimit - ",nprsell," Stop - ",stl," Take - ",tpr);
               equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
               }
            }
         else 
            {
            ticket=OrderSend(Symbol(),OP_SELLSTOP,Lots,nprsell,3,stl,tpr);
            if(ticket==-1)  Print("ErrorSellStop - ",GetLastError()); 
            else 
               {
               Print("PriceSellStop - ",nprsell," Stop - ",stl," Take - ",tpr);
               equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
               }
            }
         }
      }
   else//если только хотели изменить стоп и/или тейк
      {
      if(OrdersTotal()==0)return(0);
      OrderSelect(0, SELECT_BY_POS);
      stl=OrderStopLoss();
      tpr=OrderTakeProfit();
      if((OrderType()==0)&&(nprbuyt!=prbuyt||nprbuys!=prbuys))
         {
         if(nprbuyt!=prbuyt)
            {
            if(nprbuyt-Bid<=stlev*Point||nprbuyt==0)tpr=0;
            else tpr=nprbuyt;               
            }
         if(nprbuys!=prbuys)
            {
            if(Bid-nprbuys<=stlev*Point||nprbuys==0)stl=0;
            else stl=nprbuys;               
            }
         if(!OrderModify(OrderTicket(),OrderOpenPrice(),stl,tpr,0,CLR_NONE))Print("ErrorModifyBuy - ",GetLastError()," Stop - ",OrderStopLoss()," new Stop - ",stl," Take - ",OrderTakeProfit()," new Take - ",tpr);  
         else 
            {
            Print("ModifyBuy, Price - ",OrderOpenPrice()," Stop - ",OrderStopLoss()," Take - ",OrderTakeProfit());
            equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
            }
         }
      if((OrderType()==2||OrderType()==4)&&(nprbuyt!=prbuyt||nprbuys!=prbuys))
         {
         if(nprbuyt!=prbuyt)
            {
            if(nprbuyt-prbuy<=stlev*Point||nprbuyt==0)tpr=0;
            else tpr=nprbuyt;               
            }
         if(nprbuys!=prbuys)
            {
            if(prbuy-nprbuys<=stlev*Point||nprbuys==0)stl=0;
            else stl=nprbuys;               
            }
         if(!OrderModify(OrderTicket(),OrderOpenPrice(),stl,tpr,0,CLR_NONE))Print("ErrorModifyBuy - ",GetLastError()," Stop - ",OrderStopLoss()," new Stop - ",stl," Take - ",OrderTakeProfit()," new Take - ",tpr);  
         else 
            {
            Print("ModifyBuy, Price - ",OrderOpenPrice()," Stop - ",OrderStopLoss()," Take - ",OrderTakeProfit());
            equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
            }
         }
      if((OrderType()==1)&&(nprsellt!=prsellt||nprsells!=prsells))
         {
         if(nprsellt!=prsellt)
            {
            if(Ask-nprsellt<=stlev*Point||nprsellt==0)tpr=0;
            else tpr=nprsellt;               
            }
         if(nprsells!=prsells)
            {
            if(nprsells-Ask<=stlev*Point||nprsells==0)stl=0;
            else stl=nprsells;               
            }
         if(!OrderModify(OrderTicket(),OrderOpenPrice(),stl,tpr,0,CLR_NONE))Print("ErrorModifySell - ",GetLastError()," Stop - ",OrderStopLoss()," new Stop - ",stl," Take - ",OrderTakeProfit()," new Take - ",tpr);  
         else
            {
            Print("ModifySell, Price - ",OrderOpenPrice()," Stop - ",OrderStopLoss()," Take - ",OrderTakeProfit());
            equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
            }
         }
      if((OrderType()==3||OrderType()==5)&&(nprsellt!=prsellt||nprsells!=prsells))
         {
         if(nprsellt!=prsellt)
            {
            if(prsell-nprsellt<=stlev*Point||nprsellt==0)tpr=0;
            else tpr=nprsellt;               
            }
         if(nprsells!=prsells)
            {
      Print("Hello");
            if(nprsells-prsell<=stlev*Point||nprsells==0)stl=0;
            else stl=nprsells;               
            }
         if(!OrderModify(OrderTicket(),OrderOpenPrice(),stl,tpr,0,CLR_NONE))Print("ErrorModifySell - ",GetLastError()," Stop - ",OrderStopLoss()," new Stop - ",stl," Take - ",OrderTakeProfit()," new Take - ",tpr);  
         else
            {
            Print("ModifySell, Price - ",OrderOpenPrice()," Stop - ",OrderStopLoss()," Take - ",OrderTakeProfit());
            equal(nprbuy,nprbuyt,nprbuys,nprsell,nprsellt,nprsells);
            }
         }
      }
//----
   return(0);
  }
//+------------------------------------------------------------------+
void closeord()//закрытие ордеров
     {
      OrderSelect(0, SELECT_BY_POS);
      if(OrderType()==OP_BUY)   // long position is opened
        {
        OrderClose(OrderTicket(),OrderLots(),Bid,3,Violet); // close position
        }
      else if (OrderType()==OP_SELL)// go to short position
        {
         OrderClose(OrderTicket(),OrderLots(),Ask,3,Violet); // close position
        }
      else OrderDelete(OrderTicket() ); 
      return;
     } 
void equal(double nprbuy,double nprbuyt,double nprbuys,double nprsell,double nprsellt,double nprsells)
   {
   prbuy=nprbuy;
   prbuyt=nprbuyt;
   prbuys=nprbuys;
   prsell=nprsell;
   prsellt=nprsellt;
   prsells=nprsells;
   return;
   }     
void drawline()//рисование линий
   {
   ObjectCreate("BUY",OBJ_HLINE,0,0,Bid+2*Period()*Point);  //выставляем новые 
   ObjectSet("BUY",OBJPROP_COLOR,Aqua);
   ObjectCreate("SELL",OBJ_HLINE,0,0,Bid-2*Period()*Point);   
   ObjectSet("SELL",OBJPROP_COLOR,Yellow);
   prbuy=NormalizeDouble(ObjectGet("BUY",OBJPROP_PRICE1),Digits);
   prsell=NormalizeDouble(ObjectGet("SELL",OBJPROP_PRICE1),Digits);
   if(!NoStops)//рисование стопов и тейков
      {
      prbuyt=Bid+3*Period()*Point;
      prbuys=Bid+Period()*Point;
      prsellt=Bid-3*Period()*Point;
      prsells=Bid-Period()*Point;
      ObjectCreate("BUYT",OBJ_HLINE,0,0,prbuyt);   
      ObjectSet("BUYT",OBJPROP_COLOR,DarkTurquoise);
      ObjectCreate("BUYS",OBJ_HLINE,0,0,prbuys); 
      ObjectSet("BUYS",OBJPROP_COLOR,MediumOrchid);
      ObjectCreate("SELLT",OBJ_HLINE,0,0,prsellt);   
      ObjectSet("SELLT",OBJPROP_COLOR,Gold);
      ObjectCreate("SELLS",OBJ_HLINE,0,0,prsells);   
      ObjectSet("SELLS",OBJPROP_COLOR,DeepPink);
      }
   return;
   }