//+----------------------------------------------------------------------+
//|                                           JQS Terminator Line v1.0.0 |
//|                                       Copyright © 2010, JQS aka Joo. |
//|                                     http://www.mql4.com/ru/users/joo |
//+----------------------------------------------------------------------+
//|   Терминатор (астрономия) (от лат. terminare — ограничивать) — линия |
//| светораздела, отделяющая освещённую (светлую) часть небесного тела от|
//| неосвещённой (тёмной) части.                                         |
//|                                                                      |
//|   Терминатор (ДНК) — последовательность нуклеотидов ДНК, узнаваемая  |
//| РНК-полимеразой как сигнал к прекращению синтеза молекулы РНК и      |
//| диссоциации транскрипционного комплекса.                             |
//|                                                                      |
//|   Терминатор (электроника) — поглотитель энергии (обычно резистор) на|
//| конце длинной линии, сопротивление которого равно волновому          |
//| сопротивлению линии.                                                 |
//+----------------------------------------------------------------------+
#property copyright "Copyright © 2010, JQS aka Joo."
#property link      "http://www.mql4.com/ru/users/joo"
//-----------------------------------------------------

//-------------------Ввод глобальных переменных---------------------------
extern string   MM         = "-----------Управление капиталом--------";
extern double   K_Martin   =1.0;  //Коэфф Мартина
extern double   MinLoss    =1.0;  //Мин. возможный убыток в валюте депо
extern double   ProfitRatio=1.0;  //Отношение TP/SL
extern int      SLdefault  =20;   //Относительный размер SL
//------------------------------------------------------------------------

//-------------------Глобальные переменные--------------------------------
double TP;            //Относительный размер        
double TakeProfit;    //Абсолютная величина расстояния от TP до ask/bid
double TPline;        //Абсолютная величина лини TP

double SL;            //Относительный размер 
double StopLoss;      //Абсолютная величина расстояния от SL до ask/bid
double SLline;        //Абсолютная величина лини SL

string UsersOrderType;

double Loss;          //Текущий допустимый убыток в валюте депо
double Loss_Prev;     //Предыдущий допустимый убыток в валюте депо
double Lots_New;      //Количество лотов для новых ордеров
//------------------------------------------------------------------------

//========================================================================
int init()
{
  //-------------------------------------
  Loss_Prev=MinLoss;
  //-------------------------------------
  return;
}
//========================================================================

//========================================================================
int start()
{ 
  //-------------------------------------
  if (OrdersTotal()>=1)
  {
    ObjectDelete("SignalLineSL");
    ObjectDelete("SignalLineTP");
  } else
  {
    LineDraw();
    LineSens();
    Criterion();//Зацикленная функция
    //-------------------------------------
    OpenOrder();
    //-------------------------------------
  }
  //-------------------------------------
  return;
}
//========================================================================

//========================================================================
int deinit()
{
  //-------------------------------------
  ObjectDelete("SignalLineSL");
  ObjectDelete("SignalLineTP");
  //-------------------------------------
  return;
}
//========================================================================

//========================================================================
void Criterion()
{
  bool Flag=true;
  //-------------------------------------
  while (Flag==true)
  {
    if (LineFind()==true)
    {
      LineSens();
      Inform();
    } else
    {
      Flag=false;
    }
  }
  //-------------------------------------
}
//========================================================================

//========================================================================
void LineDraw()
{
  //-------------------------------------
  double ask;
  double bid;
  double point;
  //-------------------------------------
  string Symb=Symbol();
  ask        =MarketInfo(Symb,MODE_ASK);
  bid        =MarketInfo(Symb,MODE_BID);
  point      =MarketInfo(Symb,MODE_POINT);
  //-------------------------------------
  StopLoss   =SLdefault*point;                             //Нормализовано. Абсолютная величина расстояния от SL до ask/bid
  SLline     =bid-StopLoss;                                //Нормализовано. Ценовое значение уровня стопа
  TakeProfit =NormalizeDouble(StopLoss*ProfitRatio,Digits);//Нормализовано. Абсолютная величина расстояния от TP до ask/bid
  TPline     =ask+TakeProfit;                              //Нормализовано. Ценовое значение уровня профита
  //-------------------------------------
  //Создадим линию TP
  ObjectCreate("SignalLineTP", OBJ_HLINE, 0,  0,TPline);
  ObjectSet   ("SignalLineTP", OBJPROP_COLOR, Blue);
  //Создадим линию SL
  ObjectCreate("SignalLineSL", OBJ_HLINE, 0,  0,SLline);
  ObjectSet   ("SignalLineSL", OBJPROP_COLOR, Red);
  //-------------------------------------
}
//========================================================================

//========================================================================
void LineSens()
{
  //-------------------------------------
  RefreshRates();
  string Symb      = Symbol();
  double stoplevel = MarketInfo(Symb,MODE_STOPLEVEL)*Point;//Абсолютный размер в пунктах
  double CurrentValue;
  //-------------------------------------
  //Определим, Buy или Sell позиция
  CurrentValue       =NormalizeDouble(ObjectGet("SignalLineSL", OBJPROP_PRICE1),Digits);//Нормализованное ценовое значение уровня SL 

  //Если линия стопа ниже середины между Ask и Bid то...
  if (CurrentValue<(Ask+Bid)*0.5)
  {//...имеем дело с длинной позицией----------
    if (Bid-CurrentValue<stoplevel)
    {
      CurrentValue=Bid-stoplevel;
    }
    //Обработаем линию стопа
    UsersOrderType="Buy";
    ObjectMove("SignalLineSL",0,1, CurrentValue);//Передвинем SL на нормализованное значение уровня SL
    SLline     =CurrentValue;                    //Нормализовано. Ценовое значение уровня стопа
    StopLoss   =Bid-SLline;                      //Нормализовано. Абсолютная величина расстояния от SL до ask/bid
    SL         =StopLoss/Point;                  //Относительный размер SL в пунктах

    //Обработаем линию профита
    TakeProfit =NormalizeDouble(StopLoss*ProfitRatio,Digits);//Нормализовано. Абсолютная величина расстояния от TP до ask/bid
    TP         =TakeProfit/Point;                            //Относительный размер TP в пунктах
    TPline     =Ask+TakeProfit;                              //Нормализовано. Ценовое значение уровня профита
    ObjectMove("SignalLineTP",0,1, TPline);                  //Передвинем TP на нормализованное значение уровня TP
    //------------------------------------------
  }
  //----------------------------------------------------------
  else
  {//...имеем дело с короткой позицией---------
    if (CurrentValue-Ask<stoplevel)
    {
      CurrentValue=Ask+stoplevel;
    }
    //Обработаем линию стопа
    UsersOrderType="Sell";
    ObjectMove("SignalLineSL",0,1, CurrentValue);//Передвинем SL на нормализованное значение уровня SL
    SLline     =CurrentValue;                    //Нормализовано. Ценовое значение уровня стопа
    StopLoss   =SLline-Ask;                      //Нормализовано. Абсолютная величина расстояния от SL до ask/bid
    SL         =StopLoss/Point;                  //Относительный размер SL в пунктах

    //Обработаем линию профита
    TakeProfit =NormalizeDouble(StopLoss*ProfitRatio,Digits);//Нормализовано. Абсолютная величина расстояния от TP до ask/bid
    TP         =TakeProfit/Point;                            //Относительный размер TP в пунктах
    TPline     =Bid-TakeProfit;                              //Нормализовано. Ценовое значение уровня профита
    ObjectMove("SignalLineTP",0,1, TPline);                  //Передвинем TP на нормализованное значение уровня TP
    //------------------------------------------
  }
  //-------------------------------------
  WindowRedraw();
}
//========================================================================

//========================================================================
bool LineFind()
{
  //-------------------------------------
  if (ObjectFind("SignalLineTP")==-1)
  {
    return(false);
  } else
  {
    return(true);
  }
  //-------------------------------------
}
//========================================================================

//========================================================================
void OpenOrder()
{
  //-------------------------------------
  int    
  Ticket,    // Номер ордера
  MN;        // MagicNumber
  //-------------------------------------
  Lot();
  if (UsersOrderType=="Buy") // Будем открывать Buy
  {
    Ticket=OrderSend(Symbol(),0,Lots_New,Ask,2,SLline,TPline,"",MN);
  }
  if (UsersOrderType=="Sell") // Будем открывать Sell
  {
    Ticket=OrderSend(Symbol(),1,Lots_New,Bid,2,SLline,TPline,"",MN);
  }
  //-------------------------------------
  Comment("Откроем позицию "+ UsersOrderType+" с StopLoss=", SLline," TakeProfit=", TPline," Размер лота=",Lots_New);
  //-------------------------------------
  return;
}
//========================================================================

//========================================================================
void Lot()
{
  //-------------------------------------
  string Symb    =Symbol();                            // Финансовый инструм.
  double One_Lot =MarketInfo(Symb,MODE_MARGINREQUIRED);//Размер свободных средств, необходимых для открытия 1 лота
  double Min_Lot =MarketInfo(Symb,MODE_MINLOT);        //Мин. размер. лота
  double Step    =MarketInfo(Symb,MODE_LOTSTEP);       //Шаг изменен размера лота
  double Free    =AccountFreeMargin();                 //Свободные средства
  double LotPrice=MarketInfo(Symb, MODE_TICKVALUE);    //Стоимость 1 лота в валюте депо на 1 тик
  //-------------------------------------
  if (OrdersHistoryTotal()<1)
  {
    Loss_Prev=MinLoss;
    Lots_New=NormalizeDouble(Loss_Prev/(LotPrice*SL),2);
  } else
  {
    OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS, MODE_HISTORY);
    if (OrderProfit()<0)
    {
      Loss_Prev*=K_Martin;
      Lots_New=NormalizeDouble(Loss_Prev/(LotPrice*SL),2);
    } else
    {
      Loss_Prev=MinLoss;
      Lots_New=NormalizeDouble(Loss_Prev/(LotPrice*SL),2);
    }
  }
  //-------------------------------------
}
//========================================================================

//========================================================================
double LotInfo()
{
  //-------------------------------------
  string Symb    =Symbol();                            // Финансовый инструм.
  double One_Lot =MarketInfo(Symb,MODE_MARGINREQUIRED);//Размер свободных средств, необходимых для открытия 1 лота
  double Min_Lot =MarketInfo(Symb,MODE_MINLOT);        //Мин. размер. лота
  double Step    =MarketInfo(Symb,MODE_LOTSTEP);       //Шаг изменен размера лота
  double Free    =AccountFreeMargin();                 //Свободные средства
  double LotPrice=MarketInfo(Symb, MODE_TICKVALUE);    //Стоимость 1 лота в валюте депо на 1 тик

  double LossPrevTemp;
  double LotsNewTemp;
  //-------------------------------------
  if (OrdersHistoryTotal()<1)
  {
    LossPrevTemp=MinLoss;
    LotsNewTemp=NormalizeDouble(LossPrevTemp/(LotPrice*SL),2);
  } else
  {
    OrderSelect(OrdersHistoryTotal()-1,SELECT_BY_POS, MODE_HISTORY);
    if (OrderProfit()<0)
    {
      LossPrevTemp=Loss_Prev*K_Martin;
      LotsNewTemp=NormalizeDouble(LossPrevTemp/(LotPrice*SL),2);
    } else
    {
      LossPrevTemp=MinLoss;
      LotsNewTemp=NormalizeDouble(LossPrevTemp/(LotPrice*SL),2);
    }
  }
  //-------------------------------------
  return(LotsNewTemp);
}
//========================================================================

//========================================================================
void Inform()
{
  //-------------------------------------
  string Symb              = Symbol();
  string DepoCurrency      = AccountCurrency();                         //Наименование валюты для счета
  double MeansOneLot       = MarketInfo(Symb,MODE_MARGINREQUIRED);      //Необходимо средств для открытия 1 лота
  double MeansFree         = AccountFreeMargin();                       //Значение свободных средств, разрешенных для открытия позиций
  double MeansGuaranty     = AccountMargin();                           //Значение залоговых средств, используемых для поддержания открытых позиций
  double LotPriceTic       = MarketInfo(Symb, MODE_TICKVALUE);          //Стоимость 1 лота в валюте депо на 1 тик
  double MaxLotPermissible = MathFloor((MeansFree/MeansOneLot)*100)/100;//Максимально допустимый лот для открытия позиции
  double MaxSLPermissible;                                              //Максимально допустимый SL до StopOut

  double stopout;
  string ind;
  //-------------------------------------
  if (AccountStopoutMode()==0)
  {
    stopout=AccountStopoutLevel();
    ind    ="%";
    MaxSLPermissible  = MathFloor((MeansFree*(100-stopout))/(LotPriceTic*LotInfo()*100));
  } else
  {
    stopout=AccountStopoutLevel();
    ind    =DepoCurrency;
    //MaxSLPermissible  = MathFloor( (MeansFree-stopout)/(LotPriceTic*LotInfo()) );
  }
  //-------------------------------------   
  Comment(
         "SLline = ",SLline
         ,"\n",
         "TPline = ",TPline
         ,"\n",
         "TP     = ",TP
         ,"\n",
         "SL     = ",SL//,"  MaxSL=",MaxSLPermissible
         ,"\n",
         "Lot    =",LotInfo(),"  MaxLot=",MaxLotPermissible
         ,"\n",
         "Profit =",LotPriceTic*LotInfo()*TP,"  Loss=",LotPriceTic*LotInfo()*SL
         ,"\n",
         "Уровень стоплевела = ",MarketInfo(Symb,MODE_STOPLEVEL)
         ,"\n",
         "Спред = ",MarketInfo(Symb,MODE_SPREAD)
         );
}
//========================================================================